سبد خرید
0

سبد خرید شما خالی است.

تمام دسته ها
  • تمام دسته ها
  • Power BI
  • Power Pivot
  • Power Query
  • ابزارها
  • افزونه ها
  • اکسل مدیا
  • توابع اکسل
  • دسته‌بندی نشده
  • دیده بان
  • گوگل شیت
  • مسائل کاربردی
  • معرفی کتاب
  • نمودار ها
  • وی بی - ماکرو

فرمول نویسی با استفاده از Table

فرمول نویسی در Table
۲/۵ - (۱ امتیاز)

فرمول نویسی در Table

ما در اکسل داده ها رو ثبت، ذخیره و آماده میکنیم که بتونیم از این داده ها گزارش گیری کنیم و تحلیل هایی بدست بیاریم. داده ها در اکسل یا در قالب Range معمولی و یا در قالب Table ذخیره میشن. Range معمولی یعنی همون سلول های موجود در اکسل که بصورت A1, B10 و … شناخته میشن، اما Table متفاوت هست. وقتی یک Range در اکسل رو به Table تبدیل میکنیم، یک سری ویژگی ها پیدا میکنه که یکی از مهم ترین ویژگی هاش Structured Reference هست. در این آموزش میخواهیم راجع به فرمول نویسی در Table (که بخشی از فرمول نویسی در اکسل است) و اهمیت و کاربرد آن صحبت کنیم.

تعریف Structure Reference برای فرمول نویسی در Table

یک structured reference یا table reference یک راه ویژه برای آدرس دهی اجزای یک Table هست که بجای آدرس سلول ها، از ترکیب اسم Table و نام ستون ها استفاده میکنه.

همین موضوع Table رو در برابر Range معمولی خیلی قوی تر و منعطف تر میکنه. Range معمولی اکسل نمیتونه در برابر اضافه شدن داده، بصورت پویا، اپدیت بشه. در حالیکه یکی از ویژگی های خیلی مهم ابزارTable  همین آپدیت شدن محدوده ها بصورت خودکار هست. مثلا برای محاسبه جمع هزینه ها در D2:D9 اگر داده ها Range معمولی باشه از فرمول زیر استفاده میکنیم:

=Sum(D2:D9)

آدرس دهی در حالت Range معمولی

شکل ۱ – آدرس دهی در حالت Range معمولی

اما اگر این داده ها از جنس Table باشه، برای همین محاسبه، فرمول زیر رو مینویسیم:

=SUM (Table1[مبلغ نهایی])

آدرس دهی در حالت Table و Structured Reference

شکل ۲ – آدرس دهی در حالت Table و Structured Reference

ویژگی های اصلی Structured Reference

در مقایسه با Range معمولی، Table ها یک سری ویژگی هایی دارند که در ادامه اونها رو شرح میدهیم:

براحتی ایجاد میشوند

وقتی در فرمول نویسی میخواهیم به محدوده های خاصی از یک تیبل اشاره کنیم، فقط کافیه اون محدوده ها رو انتخاب کنیم. خودش تبدیل به ساختار مختص به Table میشه و نیازی به دانش خاصی برای این نوع فرمول نویسی نداریم.

انعطاف پذیر هستند و بصورت خودکار آپدیت میشوند

وقتی اسم یک ستون رو تغییر بدیم، فرمول هایی که از اون ستون استفاده کردن، آپدیت میشن و فرمول خراب نمیشه. اگر هم داده هایی به جدول اضافه بشه، فرمول های نوشته شده، بصورت خودکار گسترش پیدا میکنن و ردیف های جدید رو هم شامل میشن.

پس هر تغییری در Table داده ها ایجاد کنیم، در فرمول ها آپدیت میشه و مشکلی پیش نمیاد.

بصورت خودکار اتوفیل میشه

برای اینکه یک فرمول رو برای همه ردیف ها در یک تیبل داشته باشیم، کافیه فقط برای یک سلول این فرمول رو بنویسیم. فرمول بصورت خودکار در کل اون ستون اعمال میشه.

چطور Structured Reference رو ایجاد و از آنها استفاده کنیم؟

کار کردن با Structured Reference خیلی ساده هست. کافیه در ابتدا Range معمولی اکسل رو به Table تبدیل کنیم که برای این کار کافیه محدوده رو انتخاب کرده و با زدن کلید ترکیبی Ctrl+T محدوده رو تبدیل به Table کنیم. توضیحات بیشتر راجع به این موضوع رو در مقاله Table چیست ببینید.

برای ایجاد Structured Reference مراحل زیر رو باید انجام بدیم:

  1. فرض کنید میخواید فرمول معمولی بنویسید. پس با زدن = در یک سلول شروع میکنیم.
  2. بعد از نوشتن تابع مورد نظر، محدوده دلخواه رو از جدول مورد نظر انتخاب کنید. اکسل بصورت خودکار نام ستون رو فراخوانی میکنه و با توجه به نوع انتخاب محدوده ها، ساختار مناسب رو ایجاد میکنه.
  3. پرانتز پایانی تابع رو وارد کرده و Enter میزنیم. اگر فرمول داخل Table ایجاد شده باشه، بصورت خودکار، تا انتهای تیبل، فرمول اعمال میشه.

فرمول نویسی در Table

شکل ۳ – فرمول نویسی در Table

کل ردیف های Table با فرمول زیر پر میشن. همونطور که مشخصه، هیچ اسمی از آدرس سلول ها وجود نداره و فقط فیلد مقدار در نرخ ضرب شده.

=[@نرخ]*[@مقدار]

اگر فرمول رو خارج از Table وارد کنیم و در فرمول نیاز به انتخاب یک range خاص داشته باشیم بهتره طبق مراحل زیر عمل کنیم:

  1. بعد از باز شدن پرانتز تابع مورد نظر، شروع کنیم به تایپ نام Table مربوطه. به محض شروع به تایپ اولین حروف، نامهایی که با این عبارات شروع میشن نمایش داده میشن و ما میتونیم از لیست مورد نظر نام Table رو انتخاب کنیم.
  2. با استفاده از کلیدهای چهار جهت (Arrow Key) Table مورد نظر رو انتخاب میکنیم.
  3. با زدن دبل کلیک یا کلید Tab جدول مورد نظر انتخاب میشه و در فرمول نمایش داده میشه.
  4. پرانتز فرمول رو بسته و Enter رو میزنیم.

مثلا در مثال زیر، نام جدول مورد نظر ما Sale هست (اصول نامگذاری محدوده های نامگذاری رو مطالعه کنید). حالا میخواهیم بیشترین میزان فروش بین همه محصولات و در همه ماه ها رو محاسبه کنیم. برای این کار طبق توضیحات بالا از فرمول زیر استفاده میکنیم:

=MAX(sale)

انتخاب جدول در فرمول

تشریح اجزای Structured Reference برای فرمول نویسی در Table

همونطور که در بالا توضیح دادیم، نیازی به شناخت اجزای این ساختار نیست. اما درک اجزای این گونه ساختارها به فهم چگونگی عملکرد فرمول های نوشته شده کمک میکنه.

عموما یک structured reference از یک رشته ای تشکیل میشه که با نام Table مورد نظر شروع میشه و با نام ستون مورد نظر تمام میشه. به عنوان مثال، فرمول زیر رو که جمع داده های موجود در ستون شمال تا جنوب رو در ردیف جمع کل (Total) در جدولی به نام Region حساب میکنه رو ببینیم:

=SUM (region[[#Totals],[جنوب]:[شمال]])

این فرمول سه قسمت داره:

Region: نام Table مورد نظر هست.

[#Totals]: مشخص کننده آیتم مورد نظر  برای انجام عملیات.

[جنوب]:[شمال]: ستون های مورد نظر برای انجام عملیات.

تشریح اجزای Structured Reference

شکل ۴- تشریح اجزای Structured Reference

قسمت اول، نام Table

نام table به کل داده های جدول اشاره میکنه، بدون سرستون ها و بدون ردیف جمع کل (Total Row). این نام میتونه نام پیشفرض جدول ها در اکسل باشه، مثل Table1 و … یا اینکه اسم خاصی که ما براش تعیین میکنیم مثل Region . تغییر نام Table از تب Design و در قسمت Properties امکان پذیر هست.

اگر فرمول داخل خود Table نوشته بشه، بصورت پیشفرض، نام جدول از ساختار فرمول حذف میشه.

نکته:
اسم Table میتونه پارسی هم باشه. اما پیشنهاد میشه برای این کار از اسم با حروف انگلیسی استفاده بشه.

 

مشخص کننده ستون – Column Specifier

این قسمت، به داده های موجود در ستون مورد نظر اشاره میکنه. بدون سر ستون و بدون داده موجود در ردیف کل. یک Column Specifier با نام ستون که داخل براکت قرار گرفته نمایش داده میشه.

برای ارجاع دادن به بیش از یک ستون (پشت سر هم) از ساختار Range استفاده میکنیم مثلا: ][جنوب]:[شمال]]

مشخص کننده آیتم  – Item Specifier

برای ارجاع دادن به قسمت خاصی از جدول، باید از یکی از گزینه های زیر استفاده کنیم:

مشخص کننده آیتم اشاره میکنه به:
 [#All] کل جدول، شامل داده ها، سرستون ها، ردیف کل
[#Data] ردیف های داده
[#Headers] سرستون های جدول
[#Totals] ردیف کل (Total)
[@Column_Name] ردیف جاری از ستون مورد نظر

 توج داشته باشید که علامت # برای همه این موارد استفاده میشه به جز ردیف جاری. در آیتم ردیف جاری، از @ استفاده میشه برای ارجاع دادن به ردیف متناظر در سلولی که داریم فرمول رو ثبت میکنیم.

مثلا اگر بخواهیم فروش شمال و جنوب رو برای هر محصول حساب کنیم، از فرمول زیر استفاده میکنیم:

=SUM([@جنوب],[@شمال])

عملگرها لازم برای فرمول نویسی در Table

با عملگرهای زیر میتونیم ساختارهای منعطف تری رو بسازیم:

Range Operator یا :

همونطور که Range پیوسته در اکسل با : تعیین میشه مثل A1:B10 . در Table هم با همین : Range رو تعیین میکنیم. مثلا ][جنوب]:[شمال]] که به معنی ستون شمال تا جنوب هست.

Union Operator یا ,

برای ارجاع به محدوده های ناییوسته در Table از کاما استفاده میکنیم.

=SUM (region[شمال] , region[جنوب] )

Intersection Operator یا (فاصله-Space)

از این عملگر برای ارجاع دادن به یک سلول خاص در تقاطع یک ستون و یک ردیف استفاده میشه.

مثلا میخواهیم مقدار کل فروش در غرب رو از ردیف Total فراخوانی کنیم:

=Region[#Totals] Region[[#All],[غرب]]

دقت کنید در اینجا All لازمه چون نشخص کننده ستون، شامل سطر کل نمیشه. اگر اشتراکی بین دو جزء فرمول پیدا نشه با خطای NULL مواجه میشیم.

برای این کار از یک ساختار دیگه هم میشه استفاده کرد (بدون Space):

=region[[#Totals],[غرب]]

قوانین ساختار Structured Reference

برای ویرایش فرمول های نوشته شده یا ثبت فرمول ها بصورت دستی قوانین زیر رو در نظر داشته باشید:

  1. مشخص کننده های آیتم و ستون رو در براکت قرار بدید

همه مشخص کننده ها Item Specifier و Column Specifier باید داخل ]براکت[ قرار داده بشن. هر مشخص کننده ای که خود شامل یک مشخص کننده دیگه هست هم باید داخل براکت قرار بگیره.

region[[شرق] : [غرب]]

  1. مشخص کننده های تو در تو باید با , از هم تفکیک بشن

اگر هر مشخص کننده ای شامل یک یا چند مشخص کننده دیگه هست، باید با , از هم جدا بشن. مثلا:

region[[#Headers] , [شرق]]

  1. نیازی به استفاده از کوتیشن در این نوع ساختار نیست
  2. از برای کاراکترهای خاص در سرستون ها استفاده کنید

در structured reference بعضی کاراکترها معنی خاصی دارند مثل #، [ ]، ‘ . حالا اگر این کارکترها در سرستونها استفاده شده بود، برای آدرس دادن اون ستون از ‘ استفاده میکنیم. مثلا برای سرستونی که Item# هست، در مشخص کننده ستون از این ساختار استفاده میکنیم: [Item ‘#]

  1. از Space برای افزایش خوانایی فرمول استفاده کنید

برای افزایش خوانایی فرمول بصورت structured reference بین مشخص کننده ها میتونیم از Space استفاده کنیم.

=AVERAGE(region[جنوب], region[شمال], region[شرق])

آدرس دهی مطلق و نسبی در Referenced Structure

بصورت پیشفرض وقتی structured reference رو درگ میکنیم با دو حالت زیر روبرو هستیم:

  • فرمول هایی با ستون های چندتایی، مطلق هستن و زمانیکه فرمول کپی میشه، فیکس میمونن.
  • فرمول هایی با ستون های تکی، نسبی هستن و زمانیکه درگ میشن، تغییر میکنن. اما زمانیکه Copy/Paste بشن یا از کلید ترکیبی Ctrl+C یا Ctrl+V استفاده بشه، تغییر نمیکنن و فیکس باقی میمونن.

زمان هایی که بخواهیم ترکیبی از این دو حالت رو در Table داشته باشیم، راهی نیست جز کپی کردن فرمول و تغییر دستی فرمول. درگ کردن فرمو، برای ستون های تکی، موجب تغییر میشه و کپی پیست باعث فیکس موندن محدوده ها میشه. اما یکی دو تا ترفند رو معرفی میکنیم که راحت تر بتونیم با این نوع ساختار، کار کنیم.

مطلق کردن ستون تکی در Structured Reference

برای مطلق کردن یک ستون تکی، در هنگام درگ کردن فرمول، اسم ستون مورد نظر رو مشابه یک Range و با : تکرار میکنیم:

ستون تکی نسبی (متغیر هنگام درگ کردن)

Table

ستون تکی مطلق (ثابت در هنگام درگ کردن)

Table[

:
]

برا یاینکه کاربرد این موضوع رو متوجه بشیم یک مثال حل میکنیم:

در داده های زیر میخواهیم جمع فروش هر محصول رو در ماه های مختلف محاسبه کنیم. اگر فرمول رو به شکل زیر بنویسیم و به سمت راست درگ کنیم، فرمول بصورت نمایش داده شده در شکل ۵ در خواهد آمد.

آدرس دهی نسبی ستون تکی در Structured Reference

شکل ۵ – آدرس دهی نسبی ستون تکی برای فرمول نویسی در Table

همونطور که در شکل ۵ مشخص هست این فرمول غلطه و محاسباتی که می میخواهیم رو انجام نمیده. ما میخواهیم ستون Criteria range (یعنی ستون نام محصول) فیکس باشه ولی ستون Sum range (یعنی فروش هر ماه) فیکس نباشه و با درگ کردن تغییر کنه. برای اینکه بتونیم همچنان از این ساختار استفاده کنیم و در عین حال آدرس دهی نسبی و مطلق رو بصورت همزمان داشته باشیم فرمول رو بصورت زیر تغییر میدهیم.

=SUMIF(sale[[محصول]:[محصول]],$F$4,sale[ماه ۱])

همونطور که در بالا توضیح دادیم ستون های چندگانه همیشه فیکس هستن. پس از این طریق، آرگومان اول رو که میخوایم فیکس بمونه، بصورت چندگانه مینویسیم و ستون بعدی که مربوط به ماه ها است و میخواهیم نسبی باشه و تغییر کنه، بصورت تک ستون. حالا درگ میکنیم.

آدرس دهی مطلق و نسبی ستون تکی در Structured Reference

شکل ۶ – آدرس دهی مطلق و نسبی ستون تکی برای فرمول نویسی در Table

نسبی کردن ستون چندتایی در Structured Reference

همونطور که گفتیم، در هنگام درگ کردن، نسبی بودن ستون تکی و مطلق بودن ستون چندتایی، بصورت پیشفرض اتفاق می افتد. نحوه فیکس کردن ستون تکی رو که شرح دادیم. حالا ببینیم چطور میتونیم ستون های چندتایی رو نسبی کنیم.

اگر بخوایم یک Range رو در هنگام درگ کردن نسبی کنیم. باید نام جدول مورد نظر رو قبل از هر دو ستون بیاریم و براکت کلی رو هم برداریم. یعنی:

ستون چندتایی مطلق (فیکس در هنگام درگ کردن)

table[[column1]:[column2]]

ستون چندتایی نسبی (متغیر در هنگام درگ کردن)

table[column1]:table[column2]

ارجاع به ردیف جاری بصورت متغیر

[@column1]:[@column2]

 مثلا فرض کنیم میخواهیم میزان فروش هر ماه رو با ماه قبلش جمع بزنیم. برای این کار اگر فرمول رو به صورت زیر بنویسیم، فرمول کاملا فیکسه و تغییری در درگ کردن نمیکنه.

=SUM(sale[@[ماه ۱]:[ماه ۲]])

اما اگه همین فرمول رو بصورت زیر بنویسیم و درگ کنیم، محدوده بصورت نسبی تغییر خواهد کرد:

=SUM(sale[@[ماه ۱]]:sale[@[ماه ۲]])

فرمول نویسی در Table - آدرس دهی نسبی ستون چندتایی در Structured Reference

شکل ۷ – آدرس دهی نسبی ستون چندتایی در Structured Reference

نکته:
همونطور که قبلا گفته شد، اگر فرمول داخل Table نوشته بشه، اسم Table میتونه حذف بشه. در اینجا Sale در فرمول نمایش داده نمیشه.

 

در این مقاله نحوه استفاده از اجزای Table در فرمول نویسی و نحوه آدرس دهی رو تشریح کردیم. با مطالعه این مقاله خیلی راحت تر میتونیم با داده ها در ساختار table فرمول نویسی انجام بدیم.

آواتار
127

فارغ التحصیل لیسانس مهندسی صنایع، ارشد مدیریت صنعتی از دانشگاه تربیت مدرس و عاشق اکسل هستم. از سال 1388 که ترم 2 لیسانس بودم، به توصیه استاد مشاورم شروع به خوندن اکسل بصورت حرفه ای کردم و همچنان در حال مطالعه و یادگیری و البته آموزش به بقیه هستم.

دیدگاه کاربران
  • علی کیا ۲۰ تیر ۱۴۰۱ / ۱۰:۵۳ ق٫ظ

    سلام و عرض ادب.
    ممنون بابت آموزش های خوبتون.
    یک سوال داشتم در مورد فرمول نویسی در Table؛اگه بخایم فرمول شماره ردیف خودکار رو (با تابع SUBTOTAL) بنویسیم چطور میشه؟

    • آواتار
      حسنا خاکزاد ۲۱ تیر ۱۴۰۱ / ۸:۴۷ ق٫ظ

      درود
      چون نیاز به رفرنس متحرک دارید، نمیشه از sructured reference استفاده کرد
      همون فرمول معمولی رو استفاده کنید

  • محمد ۲۱ مهر ۱۴۰۰ / ۱۱:۲۸ ب٫ظ

    سلام
    من یک جدول درست کردم که حاوی فرمول است و این فرمول از سلول های خارج از جدول نیز استفاده می کند.وقتی داده ها را وارد جدول می کنیم می بینیم که هر چه به سمت پایین می آییم فرمول بهم میریزد.مثلا اگر در خانه d2 از فرمول a2+b3+c2 استفاده کنم. وقتی چندین سطر به سمت پایین حرکت کنیم یا اینکه یکسری داده را داخل جدول پیست کنیم این محاسبات بهم میریزد.مثلا در خانه d5 فرمول به این فرمول a5+b12+c5 تغییر پیدا میکنه در صورتی که ستون b یکدونه باید بیاید پایین. می بینیم که ستون ۶ تا خانه اومده پایین.
    علت چیه؟؟؟

    • آواتار
      حسنا خاکزاد ۲۴ مهر ۱۴۰۰ / ۷:۴۷ ب٫ظ

      درود بر شما
      $ ها رو چک بفرمایید

  • حمیدرضا ۸ بهمن ۱۳۹۹ / ۹:۴۱ ب٫ظ

    با سلام
    من میخوام روی یه سر ستون فرمول بنویسم ولی بعد از زدن کلید اینتر فرمول از بین میره و درست عمل نمی کنه…
    راه حلی هست برای این مشکل ؟؟

  • هانیه ۲۳ آذر ۱۳۹۹ / ۹:۵۵ ب٫ظ

    سلام ، اگه یه جدول داشته باشیم که مثلا ۳ تا ستون داشته باشه و بخوایم درصدی از یکی از ستون ها رو در یک سلول داشته باشیم باید چیکار کنیم برای مثال میخوایم وقتی اینو می نویسیم ارور نده
    ٪Table[column]

    • آواتار
      حسنا خاکزاد ۲۱ دی ۱۳۹۹ / ۴:۴۴ ب٫ظ

      درود
      سوال خیلی واضح نیست
      محاسبه درصد سوالتونه؟

  • Iman Nazari ۲ خرداد ۱۳۹۹ / ۷:۱۱ ب٫ظ

    با سلام و خسته نباشید
    نیاز دارم که در یک سلول ۲ فرمول قرار بدم، فرمول اول محاسبه خودش رو بر اساس فرمول دوم باید انجام بده. برای مثال: ۱+۲ مساوی است با ۳ در نتیجه ۳+۳ در صورتی که جواب فرمول اول میشد ۴ در نتیجه فرمول دوم میشد ۴+۳
    لطف میفرمایید توضیح بدید.
    ممنون

    • آواتار
      حسنا خاکزاد ۴ خرداد ۱۳۹۹ / ۱:۰۰ ب٫ظ

      درود
      سوال واضح نیست
      متوجه نشدم

  • فرید ۲۲ فروردین ۱۳۹۹ / ۶:۵۴ ب٫ظ

    سلام خسته نباشید
    میخواستم بدونم چجوری میشه برای مثال دومین سرستون از یک جدول رو بدست بیاریم؟

    • آواتار
      حسنا خاکزاد ۲۲ فروردین ۱۳۹۹ / ۸:۵۲ ب٫ظ

      درود
      از تابع index میتونید استفاده کنید
      offset هم جواب میده
      داخل سایت راجع به index جستجو کنید مقاله زیاد وجود داره

  • جواد ۱۰ فروردین ۱۳۹۹ / ۱۰:۲۴ ق٫ظ

    با سلام
    ببخشید فرض کنید یک جدول دارم که یک ردیف کد و یک ردیف نام هست.
    چطوری میتونم در شیت دیگر جدولی داشته باشم که وقتی کد مثلا ۱۰ زدم طبق جدولی که داشتم نام اون رو خودش بیاره؟

    مرسی

      • جواد ۱۰ فروردین ۱۳۹۹ / ۱۰:۵۰ ق٫ظ

        اخه vlookup باید خودم هر دفعه استفاده کنم.
        من میخوام تو هر سلول که کد زدم تو سلول کنار همون موقع نام بخوره.
        میشه همچین چیزی؟

        • آواتار
          حسنا خاکزاد ۱۰ فروردین ۱۳۹۹ / ۱۱:۰۷ ق٫ظ

          اگه دقیقا به همین صورت بخواید باید حتما کد نویسی VBA انجام بدید

          vlookup رو میتونید توی تعدادی سلول بنویسید (بیش از چیزی که الان اطلاعات هست) که هر موقع سلولش پر شد، خروجی رو بده

  • سعید ۲۴ اسفند ۱۳۹۸ / ۸:۵۴ ب٫ظ

    با سلام
    اول تشکر از اموزش های خوبتون. عالی و کامل هستن.
    دوم من یه سوال دارم که مربوط به این مبحث نیست ولی ممنون میشم جواب بدید.
    در پیوت تیبل متغیرهای متن جدول تنها میتونه جمع یا تعداد یا میانگین و … باشه ولی من میخوام مقدار داده سلول متناظر در جدول پیوت بشینه به عبارتی میخوام مقدار سلول در جدول پیوت عینا نشون داده بشه نه میانگین یا جمع یا …. که این مقدار میتونه متنی هم باشه

    • سامان چراغی ۲۵ اسفند ۱۳۹۸ / ۷:۳۲ ق٫ظ

      سلام
      تشکر
      برای این کار باید فیلد مورد نظر رو به قسمت Row یا Column منتقل کنید.

      • سعید ۲۵ اسفند ۱۳۹۸ / ۳:۵۲ ب٫ظ

        سلام
        تشکر از پاسخگویی
        ولی منظورم این بود که من یه ستون رو بعنوان ردیف و یه ستون رو به عنوان ردیف مشخص کردم و یه ستون دیگه رو هم برای متغیر ها (value) . ولی در جدول تشکیل شده سطر و ستون که درست هست ولی متغیرها به جای اینکه تعداد یا جمع یا میانگین و … متغیر ستون سوم باشه میخوام خود متن ستون سوم در جدول قید بشه
        در صورت امکان ایدی تلگرام و … برای سوال خصوصی بدید ممنون میشم تا بتونم توضیح بدم

        • سامان چراغی ۲۷ اسفند ۱۳۹۸ / ۱۲:۲۱ ب٫ظ

          سلام
          دقیق متوجه سوالتون نشده بودم.
          برای این کار یا باید از پاو رکوئری و قسمت Transform/pivot استفاده کنید و از Don’t Aggregate رو بزنید، یا اینکه در پیوت تیبل، Data Model ایجاد کرده و با فرمول نویسی DAX یک Measure اضافه کنید و از تابع concatenatex استفاده کنید.

ارسال دیدگاه

نشانی ایمیل شما منتشر نخواهد شد.

توسط
تومان