محاسبه مالیات حقوق سال ۱۴۰۵

محاسبه مالیات حقوق در اکسل یکی از موارد پرکاربرد هر سال است. در این مقاله سعی میکنیم که نحوه محاسبه مالیات حقوق در اکسل را با استفاده از دو روش فرمول نویسی تشریح کنیم.

محاسبه مالیات حقوق در سال ۱۴۰۵ توسط سامانه اداره مالیات و بصورت خودکار انجام می شود. در این سامانه، حقوق یک فرد را در همه شرکت هایی که مشغول به کار است و حقوق از آنها دریافت میکند را در نظر میگیرد. مثلا اگر کسی بصورت مشاوره ای و با حقوق ۱۰ میلیون تومان مشغول به کار است و در جای دیگری بصورت ثابت ماهیانه 40میلیون تومان حقوق دریافت میکند، دریافتی وی ۵۰ میلیون تومان در نظر گرفته می شود و مالیات آن پرداخت می شود. (در واقع، از آنجا که در این مثال، مشاور از معافیت خود در شرکت اول استفاده کرده است، کل مبلغ ۱۰ میلیون تومان در شرکت دوم، مشمول مالیات می شود.)

لذا می بایست قبل از پرداخت حقوق به پرسنل، ابتدا لیست حقوق به اداره مالیات ارسال شود. تا پس از محاسبه و مشخص شدن مالیات پرسنل، نسبت به ثبت مالیات حقوق در کسورات حقوق و دستمزد و فیش حقوقی اقدام کرد و در نهایت نسبت به پرداخت حقوق اقدام کرد.

اقلام و عوامل مشمول مالیات حقوق کدامند؟

حقوق یک کارگر یا کارمند از مجموعه حقوق و مزایایی تشکیل می‌شود که جمع تمام آن‌ها به عنوان دستمزد نهایی حقوق به فرد پرداخت می‌شود. پس طبق قانون حقوق، هر کدام از این مزایا که مبلغی را به حقوق اضافه می‌کند و جزو دریافتی شخص به حساب می‌آیند، موارد مشمول مالیات بر حقوق هستند. فهرست دریافتی‌ها و مزایای شغلی مشمول مالیات را در این لینک میتوانید مشاهده کنید.

جدول محاسبه مالیات و دستمزد سال ۱۴۰۵

شکل ۱- جدول مالیات حقوق

حالا میخواهیم ببینیم چطور میشود در اکسل مالیات حقوق را حساب کرد. برای این کار حقوق روشهای مختلفی دارد که در اینجا من ۲ روش را ارائه میدهیم. یکی فرمول نویسی IF تو در تو و دیگری با استفاده از منطق آرایه.

محاسبه مالیات حقوق با استفاده از IF

در این روش که یکی از روش های قدیمی است، با استفاده از مفهوم IF تو در تو مالیات هر پله را روی مابه التفاوت از پله قبل حساب میکنیم. این روش تمرین خیلی خوبی برای درک منطق IF تو در تو است.

پله اول، اگر حقوق زیر ۴۰ میلیون باشد، مالیات آن صفر است یعنی:

=if( A1< 40000000,0,

حالا اگر زیر ۸۰ میلیون باشد، وارد پله دوم میشویم یعنی بین ۴۰ تا ۸۰ میلیون. یعنی:

=if( A1< 40000000,0,
                 If (A1< 80000000, (a1-40000000)*10%,

مثال: اگر حقوق ۶۰ میلیون باشد، ۴۰ میلون آن معاف از مالیات است یعنی صفر. فقط ۲۰ میلیون (یعنی مابه التفاوت ۶۰ و ۴۰) مشمول ۱۰ درصد خواهد شد.

حالا اگر زیر ۱۰۰ میلیون باشد، وارد پله سوم میشویم یعنی بین ۸۰ تا ۱۰۰ میلیون. یعنی:

   = If( A1< 40000000,0,
             If (A1< 80000000, (a1-40000000)*10%,
             If( A1 <100000000, (A1-80000000)*15%+(40000000)*10%,

مثال: اگر حقوق ۹۰ میلیون باشد. ۱۰ میلیون (مابه التفاوت ۸۰ و ۹۰) مشمول ۱۵ درصد و ۴۰ میلیون (مابه التفاوت ۸۰ و ۴۰) مشمول ۱۰ درصد مالیات میشود.

حالا اگر زیر ۱۲۰ میلیون باشد، وارد پله چهارم میشویم یعنی بین ۱۰۰ تا ۱۲۰ میلیون. یعنی:

=if( A1< 40000000,0,
                  If (A1< 80000000, (a1-40000000)*10%,
                  If( A1 <100000000, (A1-80000000)*15%+(40000000)*10%,
                  If( A1 <120000000, (A1-100000000)*20%+(20000000)*15%+(40000000)*10%,

مثال: اگر حقوق ۱۱۰ میلیون باشد. ۱۰ میلیون (مابه التفاوت ۱۰۰ و ۱۱۰) مشمول ۲۰ درصد و ۲۰ میلیون (مابه التفاوت ۱۰۰ و ۸۰) مشمول ۱۵ درصد و ۴۰ میلیون (مابه التفاوت ۸۰ و ۴۰) مشمول ۱۰ درصد مالیات میشود. که این ۳ تا با هم جمع می شوند و حاصل ۹ میلیون تومان  میشود.

حالا اگر زیر ۱۴۰ میلیون باشد، وارد پله پنجم میشویم یعنی بین ۱۲۰ تا ۱۴۰ میلیون. یعنی:

=if( A1< 40000000,0,
                  If (A1< 80000000, (a1-40000000)*10%,
                  If( A1 <100000000, (A1-80000000)*15%+(40000000)*10%,
                  If( A1 <120000000, (A1-100000000)*20%+(20000000)*15%+(40000000)*10%,
                  If( A1 <120000000, (A1-100000000)*20%+(20000000)*15%+(40000000)*10%,
                  If( A1<140000000, (A1-120000000)*25%+(20000000)*20%+(20000000)*15%+(40000000)*10%

و حالا پله آخر یعنی بالای ۱۴۰ میلیون. اینجا دیگه IF نیازی نیست و به ازای Vale False تابع IF آخر مالیات بالای ۱۴۰ را اضافه میکنیم.

=if( A1< 40000000,0,
                   If (A1< 80000000, (a1-40000000)*10%,
                   If( A1 <100000000, (A1-80000000)*15%+(40000000)*10%,
                   If( A1 <120000000, (A1-100000000)*20%+(20000000)*15%+(40000000)*10%,
                   If( A1 <120000000, (A1-100000000)*20%+(20000000)*15%+(40000000)*10%,
                   If( A1<140000000, (A1-120000000)*25%+(20000000)*20%+(20000000)*15%+(40000000)*10%
                   ,(A1-140000000)*30%+(20000000)*25% +(20000000)*20%+(20000000)*15%+(40000000)*10%)))))

نکته: واضحه که بجای (۲۰۰۰۰۰۰۰)*۲۰% میتوانیم بنویسیم ۴۰۰۰۰۰۰ ولی بدلیل درک بهتر نحوه محاسبات، در مرحله اول کامل نوشته شده. در ادامه فرمول خلاصه شده رو مشاهده میکنید:

=if( A1< 40000000,0,
                 If (A1< 80000000, (a1-40000000)*10%,
                 If( A1 <100000000, (A1-80000000)*15%+4000000,
                 If( A1 <120000000, (A1-100000000)*20%+7000000,
                 If( A1<140000000, (A1-120000000)*25%+11000000,(A1-140000000)*30%+16000000)))))

محاسبه مالیات حقوق با استفاده از منطق آرایه

در این روش با استفاده از منطق آرایه، اختلاف حقوق و هر بازه را حساب میکنیم و بعد نتیجه را در اختلاف درصد هر پله ضرب میکنیم:

=SUMPRODUCT((A1>F2:F6)*(A1-F2:F6)*(G2:G6))

شکل ۲- محاسبه مالیات با استفاده از منطق آرایه ای

با توجه به شکل شماره ۲، در ستون G اختلاف درصدها محاسبه شده است. این فرمول ۳ قسمت دارد. قسمت اول، بررسی شرط بزرگتر بودن حقوق از کف بازه های هر پله، قسمت دوم محاسبه مقدار اختلاف حقوق با ابتدای هر بازه و در نهایت قسمت سوم میزان اختلاف درصد مالیات. در نهایت روی نتیجه همه اینها با استفاده از sumproduct جمع انجام می شود.

مثلا برای حقوق ۱۱۰ میلیونی که مالیات آن معادل ۹ میلیون تومان خواهد شد، این فرمول به شرح زیر عمل میکند:

=SUMPRODUCT({70000000;30000000;10000000;0;0}*{0.1;0.05;0.05;0.05;0.05})

طبق فرمول، حقوق هایی که از هر کف بازه بالاتره در محاسبات در نظر گرفته میشه. مثلا حقوق ۱۱۰ میلیونی دیگه وارد پله چهارم و پنجم نمیشود زیرا نتیجه گزاره شرطی  False خواهد بود که نتیجه ضرب آن در هر عددی صفر خواهد بود. در اینجا عدد ۱۱۰ را از ۴۰، ۸۰ و ۱۰۰ کم کنیم به ترتیب ۷۰، ۳۰ و ۱۰ میلیون خواهد بود که این مقادیر به ترتیب در اختلاف درصد هر پله ضرب و در نهایت جمع می شوند. ۷۰ میلیون در ۱۰%، ۳۰ میلیون در ۵% و ۱۰ میلیون در ۵% ضرب می شوند و در نهایت جمع می شوند.

روش دوم خیلی ساده تر و البته حرفه ای تر است چرا که به ازای افزایش یا کاهش پله های مالیاتی فقط کافیست محدوده های فرمول را اصلاح کنیم. دیگر نیازی به اضافه کردن IF های متفاوت و محاسبات جدید نیست. اگر با مفاهیم آرایه آشنا نیستید حتما مقالات مرتبط را در اینجا مطالعه کنید. توجه کنید در صورتی که از ورژن قبل از ۲۰۲۱ استفاده میکنید برای ثبت فرمول حتما از کلید ترکیبی Ctrl+Shift+Enter استفاده کنید. فایل نمونه را میتوانید از لینک زیر دانلود نمایید.

دانلود فایل اکسل محاسبه مالیات حقوق ۱۴۰۵

برای دانلود فایل این آموزش روی لینک زیر کلیک کنید.